JSON::XS - 正しくて高速な JSON シリアライザ/デシリアライザ

目次


名前

JSON::XS - 正しくて高速な JSON シリアライザ/デシリアライザ

JSON::XS - 正しくて高速な JSON シリアライザ/デシリアライザ (http://fleur.hio.jp/perldoc/mix/lib/JSON/XS.html)


概要

 use JSON::XS;

 # exported functions, they croak on error
 # and expect/generate UTF-8
 # エクスポートされる関数, これらはエラー時には
 # corak し, UTF-8 を期待/生成します.

 $utf8_encoded_json_text = encode_json $perl_hash_or_arrayref;
 $perl_hash_or_arrayref  = decode_json $utf8_encoded_json_text;

 # OO-interface

 $coder = JSON::XS->new->ascii->pretty->allow_nonref;
 $pretty_printed_unencoded = $coder->encode ($perl_scalar);
 $perl_scalar = $coder->decode ($unicode_json_text);

 # Note that JSON version 2.0 and above will automatically use JSON::XS
 # if available, at virtually no speed overhead either, so you should
 # be able to just:
 # JSON バージョン 2.0 以降は JSON::XS が利用可能だった場合それを
 # 自動的に使います, 仮想的には速度的なオーバーヘッドはないので,
 # 単に次のようにするこもができます:
 
 use JSON;

 # and do the same things, except that you have a pure-perl fallback now.
 # 後はさっきと同様, ただ今度はpure-perlでのフォールバックがついています.

訳注: VERSION 2.01 で to_json/from_json から encode_json/decode_json に 変更されました. 2.01 では古い関数はその旨のメッセージと共にcroakします.


説明

このモジュールは Perl データ構造の JSON への変換及びその逆処理を 行います. 第1の目標は 正しく あることであり, 第2は 高速 であることです. 後者の目標のために, C で記述しています.

バージョン 2.0 以降の JSON モジュールは, JSON と JSON::XS が 共にインストールされていた場合, JSON は JSON::XS (これは 上書きできます)へとエミュレーション(コンストラクタとメソッドの 継承による)のおかげでオーバーヘッドなしにフォールバックします. もし JSON::XS がなければバックエンドとして互換のある JSON::PP モジュールへとフォールバックするので, JSON::XS の代わりに JSON を使うことで, 必要であれば高速にもなれる, けれども C コンパイラを必要としないポータブルな JSON API を得ることができます.

このモジュールは CPAN で何番目かの JSON モジュールであり, なぜまた新しい JSON モジュールを作る必要があるのか疑問も あるでしょう. 多くの JSON モジュールはあるのですが, その いずれもきわどい部分での処理を正しく行えず, また多くの場合で そのメンテナが反応がなかったり, もはやいなかったり, 若しくは 他の理由でバグ報告を聞き入れてもらえなかったりなのです.

他の JSON モジュールとの比較に関しては, 後述の COMPARISON を 参照して下さい.

他の JSON モジュールとの比較は後述の COMPARISON を参照してください.

JSON::XS がどのように perl の値を JSON の値へと, そしてその逆を 対応づけているのかは後述の MAPPING を参照してください.

機能

正しい Unicode 処理

このモジュールは Unicode の処理の仕方を知っていて, そしてそれをいつ どのようにして行うかについてを十分にドキュメント化して, さらには"正しさ"の内容をも記述しています.

ラウンドトリップ完全性

JSON がサポートしているデータタイプだけから成る perl データ構造を シリアライズした時, それをでシリアライズしたデータ構造は Perl レベルで同一となります (例えば文字列 "2.0" がいきなり "2" に 成ったりはしません, それは文字列であるので). これにはわずかな例外があるので, それに関しては 後述の MAPPING を読んでみてください.

JSON 正当性の厳密な確認

デフォルトでは推測も不正な JSON 文字列の生成もしません, そして JSON はデフォルトでは入力としてだけ受け付けます (後者はセキュリティ的な機能です).

高速

他の JSON モジュールや Storable といったシリアライザと比較して, このモジュールはスピードにおいてもおおよそ優位性を保っています.

簡単な使い方

このモジュールはオブジェクト指向インターフェースと同様にシンプルな 関数インターフェースを持っています.

合理的で万能な出力形式

1行形式が可能と保証する一番コンパクトな形式(簡単な行ベースの プロトコルに適切), pure-ASCII 形式(Unicode をサポートしつつも 8-bit クリーンでない転送に), 若しくはきれいに整形された 形式(それを読みたいときに)から選ぶことができます. さらにはこれらの 機能を好きなように組み合わせることもできます.


関数インターフェース

以下の便利なメソッドがモジュールから提供されています. これらはデフォルトでエクスポートされます.

$json_text = encode_json $perl_scalar

与えられた Perl データ構造を UTF-8 エンコードされたバイナリ文字列 (つまり文字列にはオクテットのみが含まれる)へと変換します. エラー時には croak します.

この関数は機能的には次のコードと同一です:

   $json_text = JSON::XS->new->utf8->encode ($perl_scalar)

速くなることを除けば.

$perl_scalar = decode_json $json_text

encode_json の反対: UTF-8 (バイナリ)文字列であることと UTF-8 エンコードされた JSON テキストとしてパースを試みること, そして結果として得たリファレンスを返すこと除いて. エラー時には croak します.

この関数は機能的には次のコードと同一です:

   $perl_scalar = JSON::XS->new->utf8->decode ($json_text)

速くなることを除けば.

$is_boolean = JSON::XS::is_bool $scalar

渡されたスカラーが JSON::XS::true 若しくは JSON::XS::false を表現していれば真を返します, この2つの定数はそれぞれ 1 及び 0 のように振る舞い JSON の true 及び false の値を Perl で表現するために 使われます.

JSON での値がどのように Perl にマッピングされるかは, 後述の"マッピング" を参照してください.


UNICODE と PERL に関する補足

これはしばしば混乱のもととなっているので, バグを法として, Perlの中で Unicode がどのように動作しているか についていくつかはっきりさせておきます.

1. Perl の文字列には順序値>255となる文字を格納できる

これによって Unicode 文字を Perl 文字列において1文字として 格納することができます - とても自然ですね.

2. Perl は文字列にエンコーディングを関連づけない

... それを強制するのまでは. 例えば正規表現にマッチさせる, スカラーをファイルに出力するといったことを行った場合, Perl は文字列を設定に応じてロケールにエンコードされたテキスト, オクテット/バイナリ, 若しくはUnicodeとして処理されます. データと一緒にエンコーディングが記録されることはありません, エンコーディングを決定するのは不思議なメタデータなどではなく 使い方です.

3. 内部の utf-8 フラグは文字列に対してエンコーディングを 考慮しているかを示している訳ではない

Perl のバグ若しくは XS で書かれたモジュールをデバッグしている, 若しくは perl の内部に飛び込みたいのいずれでもないのなら, このフラグは無視してください. それらの時以外は混乱するだけです, その名前にも関わらず, 文字列がエンコードされているかを全く伝えません. このフラグが設定されていてもいなくとも Unicode 文字列を持つことはでき, このフラグが設定されていてもいなくともバイナリデータを持つことができます. その他の可能性もあります.

もしこのフラグについて知らないのであれば, それはよいことであり, それが存在しないかのように振る舞っていてください.

4. "Unicode文字列"は単に個々の文字をUnicodeコードポイントとして 正常に処理できる文字列です.

もし UTF-8 エンコードされたデータを持っているのなら, それはもはや Unicode 文字列ではなく, バイナリ文字列を提供提供している UTF-8 でエンコードされた Unicode 文字列です.

5. "大きな" (> 255)文字値を含んだ文字列は UTF-8 文字列ではありません.

事実です. 受け入れてください.

一助になれば幸いです :)


オブジェクト指向インターフェース

オブジェクト指向インターフェースを使うことで好きなエンコード及び デコード形式をサポートされている中でではありますが選ぶことが できます.

$json = new JSON::XS

JSON 文字列絵をデコード/エンコードするための新しい JSON::XS オブジェクトを生成します. 以下で説明されている全ての真偽フラグは デフォルトでは 無効 になっています.

フラグの変更を行うメソッドは全て JSON オブジェクトを再び返すので 呼び出しは連続して行えます:

   my $json = JSON::XS->new->utf8->space_after->encode ({a => [1,2]})
   => {"a": [1, 2]}
$json = $json->ascii ([$enable])
$enabled = $json->get_ascii

$enable が真の時(若しくは省略された時), encode メソッドは 0..127 (つまりASCII) 以外の範囲の文字を生成しなくなります. この範囲にない全ての Unicode 文字は RFC 4627 にあるように \uXXXX (BMP文字)か2つの \uHHHH\uLLLL エスケープシーケンスで 表現されます. エンコードされた JSON テキストの結果は ネイティブなUnicode文字列, ascii-エンコード, latin1-エンコード 若しくは UTF-8 エンコードされた文字列, 若しくはそれ以外の ASCII の スーパーセットとして扱うことが出来ます.

$enable が偽であれば, encode メソッドは JSON 構文若しくは 他のフラグによって 必要とされているのでなければ Unicode 文字をエスケープしません. これによってフォーマットが高速でコンパクトになります.

このドキュメントの後の方に出てくる ENCODING/CODESET FLAG NOTES も参照してください.

このフラグは主にエンコードされた JSON テキストが 8 bit 文字を 全く含めることが出来ない 7-bit 経路を通して転送するために 使います.

  JSON::XS->new->ascii (1)->encode ([chr 0x10401])
  => ["\ud801\udc01"]
$json = $json->latin1 ([$enable])
$enabled = $json->get_latin1

$enable が真の時(若しくは省略された時), encode メソッドは 0..255 の範囲にない全ての文字をエスケープして, JSON テキストを latin1 (若しくは iso-8859-1)として エンコードします. 結果として得られる文字列は latin1-エンコードされた JSON テキスト若しくはネイティブなUnicode文字列として扱うことが できます. decode メソッドはこのフラグでは何も影響を起こしません, decode は厳密に latin1 のスーパーセットであるUnicodeを デフォルトで想定しているためです.

$enable が偽であれば, encode メソッドは JSON 構文若しくは 他のフラグで必要とされなければ Unicode 文字をエスケープしません.

このドキュメントの後の方に出てくる ENCODING/CODESET FLAG NOTES も参照してください.

このフラグは主にバイナリデータを JSON テキストとして効率的に, 多くのオクテットをエンスケープせず, サイズをあまり増やさずに エンコードすることを目的としています. 欠点として結果として 得られる JSON テキストは latin1 でエンコードされていて (そして格納や転送は適切に行われなければなりません), これは JSON のエンコードではあまり使われていません. けれどもこれは他の JSON エンコーダ/デコーダとやりとりする時ではなく, ファイルやデータベースに効率的にバイナリデータを含めるために知られている データ構造を格納したい時にとても役立ちます.

  JSON::XS->new->latin1->encode (["\x{89}\x{abc}"]
  => ["\x{89}\\u0abc"]    # (perl syntax, U+abc escaped, U+89 not)
$json = $json->utf8 ([$enable])
$enabled = $json->get_utf8

$enable が真の時(若しくは省略された時), encode メソッドは 多くのプロトコルが要求するように JSON 文字列を UTF-8 へと エンコードし, decode メソッドは UTF-8 エンコードされた文字列を 処理するようになります. UTF-8 文字列には 0..255 の範囲外の文字を 含まないことに注意してください, これはバイト/バイナリ I/O に 役立ちます. 今後のバージョンではこのオプションを有効にすることで RFC 4627 に書かれているように UTF-16 及び UTF-32 エンコーディング ファミリを自動認識するようになるかもしれません.

$enable が偽の時には encode メソッドは (エンコードされていない) Unicode 文字列として JSON 文字列を返し, decode は Unicode 文字列を 処理するようになります. デコーディング若しくはエンコーディング (つまり UTF-8 若しくは UTF-16)は自分で行う必要があります, つまり Encode モジュールを使って.

このドキュメントの後の方に出てくる ENCODING/CODESET FLAG NOTES も参照してください.

例, UTF-16BE でエンコードされた JSON を出力:

  use Encode;
  $jsontext = encode "UTF-16BE", JSON::XS->new->encode ($object);

例, UTF-32LE でエンコードされた JSON のデコード:

  use Encode;
  $object = JSON::XS->new->decode (decode "UTF-32LE", $jsontext);
$json = $json->pretty ([$enable])

このメソッドは indent, space_before, そして space_after のフラグの全てを一度の呼び出しで一番読みやすい(若しくはコンパクトな) 形式の生成に有効に(若しくは無効に)します.

例, シンプルな構造をきれいに出力:

   my $json = JSON::XS->new->pretty(1)->encode ({a => [1,2]})
   =>
   {
      "a" : [
         1,
         2
      ]
   }
$json = $json->indent ([$enable])
$enabled = $json->get_indent

$enable が真の時(若しくは省略された時), encode メソッドは 出力に複数行の形式をつかって全ての配列メンバやオブジェクト/ハッシュの キー-値ペアをそれぞれ独立した行に適切に区別して配置するように なります.

$enable が偽の時, 改行やインデントは生成されなくなり, 返される JSON テキストは newline を含んでいないことが 保証されます.

この設定は JSON テキストのデコードには影響しません.

$json = $json->space_before ([$enable])
$enabled = $json->get_space_before

$enable が真の時(若しくは省略された時), encode メソッドは JSON オブジェクトで キーと値を隔てている : の前に空白を 入れるようになります.

$enable が偽の時, encode メソッドはそこに余計な空白を いれなくなります.

この設定は JSON テキストのデコードには影響しません. この設定はたいてい space_after と一緒に使われるでしょう.

例, space_before が有効で space_after と indent を無効にした時:

   {"key" :"value"}
$json = $json->space_after ([$enable])
$enabled = $json->get_space_after

$enable が真の時(若しくは省略された時), encode メソッドは JSON オブジェクトでキーと値を隔てている : の後ろと, キー-値ペアや配列メンバの間にある , の後に空白を入れるように なります.

$enable が偽の時, encode メソッドはそこに余計な空白を いれなくなります.

この設定は JSON テキストのデコードには影響しません.

例, space_before と indent が無効で space_after を有効にした時:

   {"key": "value"}
$json = $json->relaxed ([$enable])
$enabled = $json->get_relaxed

$enable が真の時(若しくは省略された時), decode メソッドは 通常の JSON 構文に対する幾つかの拡張(後述)を受け付けるようになります. encode には何も影響しません. このオプションを使うと正規でない JSONテキストを正規であるかのように受け付けるようになります! このオプションはアプリケーションに特化した人の読めるファイル (設定ファイル, リソースファイルなど)をパースするときにのみ使うべきでしょう.

$enable が偽の時(デフォルト), decode は有効なJSONテキストのみを 受理するようになります.

現状受理される拡張は以下の通り:

* リスト要素の末尾のコンマ

JSON は配列の要素やキー-値ペアをコンマで区切ります. これはJSONテキストを手で書いていて要素を簡単に追加できるようにしたい 時には非常に煩わしくなります, そこでこの拡張ではそれらの間ではなく 終わりにあるコンマも受け付けます:

   [
      1,
      2, <- this comma not normally allowed
   ]
   {
      "k1": "v1",
      "k2": "v2", <- this comma not normally allowed
   }
* shell-スタイルの '#'-コメント

JSON が白空白を受け付ける箇所において, shell-スタイルのコメントも 追加で受理します. これは最初の復帰(carriage-return) 若しくは行末(line-feed)文字で終わり, その後にさらに白空白やコメントを 受け付けます.

  [
     1, # this comment not allowed in JSON
        # neither this one...
  ]
$json = $json->canonical ([$enable])
$enabled = $json->get_canonical

$enable が真の時(若しくは省略された時), encode メソッドは キーをソートした形で JSON オブジェクトを出力ようになります. これは幾分大きめのオーバーヘッドになります.

$enable が偽の時, encode メソッドはキー-値ペアを Perl が 格納している順番に出力するようになります(同じスクリプトでも 実行するたびに変化するでしょう).

このオプションは同じデータ構造からは(そして同じ設定であれば) 同一の JSON テキストにエンコードしたい時に役に立つでしょう. これが無効になっているときには同じハッシュで同じデータを 含んでいても Perl ではキー-値ペアは順序を継承しないため 異なった文字列へとエンコードされるでしょう.

この設定は JSON テキストのデコードには影響しません.

$json = $json->allow_nonref ([$enable])
$enabled = $json->get_allow_nonref

$enable が真の時(若しくは省略された時), encode メソッドは リファレンスではない値を適切な文字列, 数値, 若しくは null の JSON 値へと変換します, これは RFC 4627 に対する拡張です. decode はそのような JSON 値を croak するのではなく 受け入れるようになります.

$enable が偽の時, encode メソッドは JSON テキストはオブジェクトか 配列でなければならず, 配列リファレンスでもハッシュ リファレンスでもないものが渡されたときには例外を投げるようになります. 同じように, decode は JSON オブジェクトか配列ではない何かが 与えられたときには croak するようになります.

例, Perl スカラーを allow_nonref を有効にして JSON 値へと エンコードすると無効な JSON テキストを生成します:

   JSON::XS->new->allow_nonref->encode ("Hello, World!")
   => "Hello, World!"
$json = $json->allow_unknown ([$enable])
$enabled = $json->get_allow_unknown

$enable が真の時(若しくは省略された時), encode メソッドは JSON で表現できない値(例えばファイルハンドル)に遭遇したときに 例外を投げなくなり, その代わりに JSON の null 値へと エンコードするようになります. ブレスされたオブジェクトはこの設定には含まれず, それらは allow_nonref で別に処理されます.

$enable が偽の時(デフォルト), encode メソッドは JSON としてエンコードできない何かを見つけると 例外を投げます.

このオプションは decode には全く影響しません, また, 通信相手を知っている場合以外では無効にしておくことを 推奨します.

$json = $json->allow_blessed ([$enable])
$enabled = $json->get_allow_blessed

$enable が真の時(若しくは省略された時), encode メソッドが ブレスされたリファレンスに遭遇したとき嘔吐しなくなります. 代わりに, convert_blessed オプションの値によって null (convert_blessed 無効若しくは TO_JSON メソッドが 見つからなかった)若しくはオブジェクトの表現(convert_blessed が 有効で TO_JSON メソッドが見つかった)のどちらにエンコード されるかが決まります. decode には影響しません.

$enable が偽のとき(デフォルト)は, encode は ブレスされたオブジェクトに遭遇した時は例外を投げます.

$json = $json->convert_blessed ([$enable])
$enabled = $json->get_convert_blessed

$enable が真の時(若しくは省略された時), encode メソッドは ブレスされたオブジェクトと東宮した時にオブジェクトのクラスに TO_JSON メソッドが有効かどうかを調べます. もし見つかれば, それはスカラーコンテキストで呼ばれ, その復帰値のスカラーが オブジェクトの代わりにエンコードされます. もし TO_JSON メソッドが見つからなければ, allow_blessed の値で どうするかが変わります.

TO_JSON メソッドでは必要であれば die を安全に呼び出すことが できます. もし TO_JSON が別のブレスされているオブジェクトを 返したのであれば, それは同じように処理されます. TO_JSON は この時に終わらない無限再帰(==クラッシュ)を起こさないように 気をつけなければなりません. TO_JSON の名前は Perl コアによって 呼ばれる他のメソッド(==オブジェクトの使用者によってではなく)は 大抵大文字であることと, to_json 関数との衝突を回避するために 選ばれました.

この設定は流暢な decode というわけではまだありませんが, 将来的には, 流暢に decode できてこの設定によって有効にできる グローバルフックがインストールされるでしょう.

$enable が偽であったときには, ブレスされたオブジェクトが 見つかったときに何を行うかは allow_blessed 設定で 決定されます.

$json = $json->filter_json_object ([$coderef->($hashref)])

$coderef が指定されたときには, JSON オブジェクトをデコードするたびに decode から呼び出されます. この時の唯一の引数は新しく作られた ハッシュへのリファレンスです. もしコードリファレンスが 単一のスカラー(リファレンスである必要はありません)を返すと, この値(つまりエイリアスを回避するためにこのスカラーのコピー)は デシリアライズされるデータ構造に挿入されます. もし空のリスト (補足: 有効なスカラーである undef ではありません)が 返されると, 元のデシリアライズされたオブジェクトが挿入されます. この設定はデコードをかなり遅くさせます.

$coderef が省略されたとき若しくは未定義だったときには, 既存のコールバックは削除され, decode はデシリアライズされた ハッシュを全く変更しなくなります.

全ての JSON オブジェクトを整数 5 へと変換する例:

   my $js = JSON::XS->new->filter_json_object (sub { 5 });
   # returns [5]
   $js->decode ('[{}]')
   # throw an exception because allow_nonref is not enabled
   # so a lone 5 is not allowed.
   $js->decode ('{"a":1, "b":2}');
$json = $json->filter_json_single_key_object ($key [=> $coderef->($value)])

かすかに filter_json_object のようにも動作しますが, $key という名前のキーを1つもっている JSON オブジェクトに 対してのみ呼び出されます.

この $codereffilter_json_object を通して指定される前に 呼び出されます. これには JSON オブジェクトのその1つの値が 渡されます. もしそれが1つの値を返すと, それがデータ構造に挿入されます. もしそれが何も返さなければ(やはり空のリストではなく undef だったとき ではありません), 単一キーコールバックが指定されなかったかのように 続けて filter_json_object のコールバックが呼び出されます.

$coderef が省略されたとき若しくは未定義だったときには, 対応するコールバックは無効にされます. 与えられたキーに対して 1つのコールバックのみが存在できます.

このコールバックは filter_json_object よりも呼び出される回数が少ないので, デコードの速度はそんなには影響しないでしょう. そのために 単一キーオブジェクトは Perl オブジェクトを優秀にシリアライズ できるでしょう, 特に単一キーの JSON オブジェクトはタイプタグのついた 値というコンセプトと同じくらい類似したものを JSON として得ます (これは基本的にID/VALUEの組). もちろん, JSON がこれをサポートしてる のではないのでシリアライズされた Perl ハッシュのようにも見える この構造を使わないようにする必要があります.

この単一オブジェクトのための典型的なキーの名前としては, 実際のハッシュと衝突しないように __class_whatever__ 若しくは $__dollars_are_rarely_used__$ 若しくは }ugly_brace_placement, 若しくは __class_md5sum(classname)__ といった ものがよいでしょう.

{ "__widget__" => <id> } の形式の JSON オブジェクトを 対応する $WIDGET{<id>} オブジェクトへとデコードする例:

   # return whatever is in $WIDGET{5}:
   # $WIDGET{5} にある何かを返す:
   JSON::XS
      ->new
      ->filter_json_single_key_object (__widget__ => sub {
            $WIDGET{ $_[0] }
         })
      ->decode ('{"__widget__": 5')

   # this can be used with a TO_JSON method in some "widget" class
   # for serialisation to json:
   # これは何らかの"widget"クラスでjsonへとシリアライズする為の
   # TO_JSON でも使うことが出来ます.
   sub WidgetBase::TO_JSON {
      my ($self) = @_;

      unless ($self->{id}) {
         $self->{id} = ..get..some..id..;
         $WIDGET{$self->{id}} = $self;
      }

      { __widget__ => $self->{id} }
   }
$json = $json->shrink ([$enable])
$enabled = $json->get_shrink

Perl は文字列用のスペースを確保する時に通常わずかに多めのメモリを 確保します. この省略可能なフラグは encode 若しくは decode が生成する文字列を出来る限り小さくリサイズします. これは JSON テキストが とてもとても長くなったり短い文字列がたくさん出来たときにメモリ消費を 押さえることが出来ます. これは可能であれば文字列をオクテット形式へと 変換することも試みます: perl は内部的に文字列を UTF-X かオクテット 形式のどちらかのエンコーディングで格納します. 後者は全てを 格納できるわけではありませんが一般的に少ないメモリしか使いません (そして幾つかのバグリ気味な Perl や C のコードは使われている内部表現に 依存しているかもしれません).

shrink が行うことの実際の定義は今後のバージョンで変わるかもしれませんが, 常に時間と引き換えに使用している空間の削減を行います.

$enable が真の時(若しくは省略された時), encode メソッドから 返される文字列はぴったり合うように shrink され, そして decode が生成する全ての文字列もまた shrink されています.

$enable が偽の時は, 通常の perl でのメモリ確保アルゴリズムが使われます. あなたのデータを使って作業しているのなら, これは速くなるでしょう.

今後, この設定は空間を節約するために他のこと, 例えば整数や小数っぽい 文字列は内部的に数値や小数に変換する(これらは Perl レベルでは違いは ありません)といったことも行うようになるかもしれません.

$json = $json->max_depth ([$maximum_nesting_depth])
$max_depth = $json->get_max_depth

エンコードやデコード時に許可する最大のネストレベルを設定します( デフォルトは 512 です). もし JSON テキストか Perl データ構造に おいてより大きなネストレベルが検出されると, エンコーダ及び デコーダは停止してその時点で coark します.

ネストレベルはその地点にたどり着くまでにエンコーダが巡回する必要が あったハッシュや配列リファレンスの数若しくは文字列中で 与えられた文字にたどり着くまでに横切った { 若しくは [ 文字のうち閉じ括弧と対応していないものの数と定義しています.

最大深度を1に設定すると一切のネストを許さなくなり, これは オブジェクトがただ1つのハッシュ/オブジェクト若しくは配列のみで あることを保証します.

引数が与えられなかった場合, とりうる最大の設定がつかわれますが, これが役に立つのは稀なことでしょう.

ネストは C の再帰で実装されています. デフォルト値は 一般的なオペレーティングシステムでクラッシュしない程度の 大きさを選んでいます.

これがなぜ便利なのかの詳しい情報は SECURITY CONSIDERATIONS を 参照してください.

$json = $json->max_size ([$maximum_string_size])
$max_size = $json->get_max_size

デコードが行われようとしたときに JSON テキストの持つことのできる 最大長を(バイトで)設定します. デフォルトは制限を行わないことを意味する 0 です. decode がこのバイト数を超える長さの文字列に対して 呼び出されたときはその文字列のデコードを行うのではなく例外を発生させます. この設定は encode には(今のところ)影響しません.

引数が与えられなかったときには, 制限チェックは無効にされます (0を指定されたときと同じです).

これがなぜ便利なのかの詳しい情報は SECURITY CONSIDERATIONS を 参照してください.

$json_text = $json->encode ($perl_scalar)

与えられた Perl データ構造(単純なスカラ若しくはハッシュか配列への リファレンス)をその JSON 表現へと変換します. 単純なスカラは JSON 文字列か数値シーケンスへと変換され, 配列へのリファレンスは JSON 配列になり, ハッシュへのリファレンスは JSON オブジェクトと なります. Perl の未定義値 (例えば undef)は JSON の null 値に なります. true 若しくは false の値も生成されるでしょう.

$perl_scalar = $json->decode ($json_text)

encode の反対です: JSON テキストを受け取ってそのパースを試し, 取り出した単純なスカラかリファレンスを返します. エラー時には croak します.

JSON の数字と文字列は単純な Perl スカラーになります. JSON の配列は Perl の配列リファレンスとなり JSON オブジェクトは Perl ハッシュリファレンスになります. true1 に, false0 に, そして nullundef になります.

($perl_scalar, $characters) = $json->decode_prefix ($json_text)

これは decode メソッドのように動作しますが, 最初の JSON オブジェクトの後でゴミを引きずっているときに例外を 発生させる代わりに静かにそこでパースを停止してそこまでに消費した 文字数を返します.

これは JSON テキストが(その最初の場所で一番輝いてるのではなくて) 別のプロトコルで区切られていないけれど JSON テキストの終わる場所を知る必要があるときに便利です.

   JSON::XS->new->decode_prefix ("[1] the tail")
   => ([], 3)

少しずつのパース

いくつかのケースにおいて, JSON テキストを少しずつ(インクリメンタルに) パースすることが必要な場面もあるでしょう. このモジュールは常に JSON テキストとそこから得られた Perl データ構造を メモリに同時に保持しているので, JSON ストリームを少しずつパースすることも 可能です. これは JSON オブジェクト全体が得られるまで, デコードできる テキストになるまで蓄積することにとって実現しています. この処理は完全な JSON オブジェクトが提供されているのなら decode_prefix を使った場合と似たような感じになります, しかしもっとより効率的です (そして最小限のメソッド呼び出しで実装されています).

JSON::XS は本当に単純な, けれども 真にインクリメンタルなパーサーを使って, JSON テキストを一度のみ 結果を決定定期に得るのに十分な分のみをパースします). これは完全なパーサでは早すぎて止めれないことを意味します, 例えば, 括弧の不一致を検出できません. これが唯一保証することは, 構文的に正しい JSON テキストがあれば それをすぐにデコードを開始することのみです. これは構文エラーの時にパーサがその場でパースを停止するように保証するために リソース制限(例えばmax_size)を設定する必要があることを意味します.

インクリメンタルパーサは以下のメソッドで実現されています.

[void, scalar or list context] = $json->incr_parse ([$string])

これがパース関数の中心です. 新しいテキストを追加することもこれまでに蓄積されたストリームから オブジェクトを取り出すこともできます(この機能はどちらも任意です).

$string が与えられたときには, $json オブジェクトに保存されている JSON の断片にその文字列を 追加します.

その後, 関数が void コンテキストで呼ばれていればそれ以上はなにも しないで帰ります. この機能によって必要なだけ断片となっている テキストを追加していくことができます.

メソッドがスカラーコンテキストで呼び出されていた場合には, JSON オブジェクトを1つだけ取り出そうとしてみます. もしそれが出来ればそのオブジェクトを返し, それが出来なければ undef を返します. もしパースエラーが あれば, このメソッドは decode と同じように croak します (エラーとなった箇所を飛ばすためには incr_skip を使います). これがこの関数のよくあるな使い方でしょう.

そして最後に, リストコンテキストだった場合には, ストリームから複数のオブジェクトを取り出して返そうとします, もしくは取り出せなければ空のリストを返します. これが動作するためには JSON オブジェクト若しくは配列が 区切りなしに連続して結合していなければなりません. もしエラーが起きた場合には, スカラーコンテキストの場合と同様に 例外が発生します. この時それまでにパースされた JSON テキストは 失われる点に注意してください.

$lvalue_string = $json->incr_text

このメソッドは現在保存されている JSON の断片を lvalue として返します, つまりこれを処理することも出来ます. これはそれまでに incr_parseスカラーコンテキストで 正常にオブジェクトを返した後でのみ正常に動作します. それ以外の状況ではこの関数を呼び出しではいけません (と私は思います. 簡単なテストでは実際に動きますが, 実運用の環境では失敗となるでしょう). 特殊な例外として, 何かをパースさせる前にこのメソッドを 呼ぶことが出来ます.

この関数は2つのケースで役に立ちます: a) JSON オブジェクトの後に残っているテキストを見つけるとき 若しくは b) JSON テキスト以外(例えばコンマ)で区切られている 複数の JSON オブジェクトをパーすするとき.

$json->incr_skip

これはインクリメンタルパースの状態をリセットし, 入力バッファからパースされたテキストを取り除きます. これは incr_parse が die した時に, その時はまだ入力バッファと内部状態がそのまま残っているので, それまでにパースされたテキストをスキップして, パース状態をリセットするのに 役に立ちます.

$json->incr_reset

これはインクリメンタルパースを完全にリセットします, つまり, これを呼び出した後は, パーサはあたかも何もパースしていないかのような 状態になります.

これは JSON オブジェクトを繰り返しパースしたいけれど 後ろにくっついているデータは無視したい, つまりデコードの後に パーサをリセットする必要があるときに役に立ちます.

制限

デコードに作用する全てのオプションは allow_nonref 以外 サポートされています. これは動作が明白に鳴らないためです: JSON オブジェクト及び配列は それ自身で区切られています, つまり, オブジェクトをぴったりくっつけても それらは完璧にデコード可能です. とは行ってもこれは JSON 数値においてはその限りではありません.

例えば, 文字列 1 は単一の独立した JSON 数値でしょうか, それとも 12 の最初の部分でしょうか? では 12 が単一の独立した JSON 数値でしょうか, それとも 12 が結合された物でしょうか. どちらの場合においても間違ってはおらず, これが JSON::XS がこれらのケースを許容しないで保守的な立場を取る理由です.

いくつかの例を挙げることでより分かりやすくなるでしょう. 先ず, decode_prefix と同じように動作する簡単な例から始めてみましょう: 文字列の最初から JSON オブジェクトをデコードして, JSON オブジェクトの後にある部分を区別してみたいとしましょう:

   my $text = "[1,2,3] hello";

   my $json = new JSON::XS;

   my $obj = $json->incr_parse ($text)
      or die "expected JSON object or array at beginning of string";

   my $tail = $json->incr_text;
   # $tail now contains " hello"

簡単ですね.

ではもうちょっと複雑な例を見てみましょう: TCP ストリームからいくつかのリクエストを読み込むような 仮想的なプロトコルを想像してみましょ, そして各リクエストは JSON 配列で, それらの間には区切りを持ちません (実際には改行文字が"区切り"としてよく使われていて, それは JSON テキストの始まりでは白空白として処理されます, これがあると telnet でプロトコルをしゃべってみることができます...)

次にあるのが実際に行う処理です (これをイベントベースで記述するのも 簡単でしょう):

   my $json = new JSON::XS;

   # read some data from the socket
   # ソケットからデータをいくらか読み込み.
   while (sysread $socket, my $buf, 4096) {

      # split and decode as many requests as possible
      # 複数のリクエストを可能な分だけ分割してデコード.
      for my $request ($json->incr_parse ($buf)) {
         # act on the $request
         # $request で何か動作.
      }
   }

もうちょっと複雑な例もやってみましょう: JSON オブジェクト若しくは配列がコンマ文字で(省略可能に) 区切られている文字列を持っているとしましょう(例えば [1],[2], [3]). これらをパーすするには JSON テキストの間にあるコンマを読み飛ばす 必要があり, ここで incr_text のlvalue 特性が役に立ちます:

   my $text = "[1],[2], [3]";
   my $json = new JSON::XS;

   # void context, so no parsing done
   # void コンテキスト, つまりパースは行わない.
   $json->incr_parse ($text);

   # now extract as many objects as possible. note the
   # use of scalar context so incr_text can be called.
   # そして可能な分だけ複数のオブジェクトを取り出し.
   # incr_text が呼び出せるようにスカラーコンテキストを使用.
   while (my $obj = $json->incr_parse) {
      # do something with $obj
      # $obj で何かする.

      # now skip the optional comma
      # そして省略可能なコンマを読み飛ばす.
      $json->incr_text =~ s/^ \s* , //x;
   }

ではもっと複雑な例にいってみましょう: とっても大きな JSON のオブジェクトの配列があるとしましょう, これは数ギガバイトありますが, それを読み込みたいとします, とは行ってもそれを一度にメモリ上に読み込むことは出来ません (これは実際に起こることです:).

えぇ, あなたの負けです, 自分で JSON パーサを実装しなければなりません. けれども JSON::XS はまだその手助けをすることが出来ます: あなたが(とても単純な)配列パーサを実装して, JSON::XS に配列の要素をデコードさせることで, これはその完全な JSON オブジェクトを手に入れることになります (でもこれは例えば配列の要素が JSON 数値だった場合にはうまくいかない でしょう):

   my $json = new JSON::XS;

   # open the monster
   # 怪物を開く.
   open my $fh, "<bigfile.json"
      or die "bigfile: $!";

   # first parse the initial "["
   # 開始の "[" をパース.
   for (;;) {
      sysread $fh, my $buf, 65536
         or die "read error: $!";
      $json->incr_parse ($buf); # void context, so no parsing
                                # void context, つまりパースはまだしない.

      # Exit the loop once we found and removed(!) the initial "[".
      # In essence, we are (ab-)using the $json object as a simple scalar
      # we append data to.
      # 開始の "[" が見つかってそれを取り除い(!)たらすぐにループを抜ける.
      # 実際のところ単なるデータ積み置き用のスカラーの代わりに
      # $json オブジェクトを利用(濫用)しています.
      last if $json->incr_text =~ s/^ \s* \[ //x;
   }

   # now we have the skipped the initial "[", so continue
   # parsing all the elements.
   # で, 開始の "[" は読み終わったので,
   # 全ての要素の読み込みに移ります.
   for (;;) {
      # in this loop we read data until we got a single JSON object
      # このループの中で JSON オブジェクトを1つ得るまで
      # データを読み込み.
      for (;;) {
         if (my $obj = $json->incr_parse) {
            # do something with $obj
            # $obj に何かする.
            last;
         }

         # add more data
         # データを追加.
         sysread $fh, my $buf, 65536
            or die "read error: $!";
         $json->incr_parse ($buf); # void context, so no parsing
                                   # void context, つまりパースはまだしない.
      }

      # in this loop we read data until we either found and parsed the
      # separating "," between elements, or the final "]"
      # こちらのループでは要素区切りの "," か終端の "]" を
      # 見つけて取り除くまでデータを読み込み.
      for (;;) {
         # first skip whitespace
         # まず白空白の除去.
         $json->incr_text =~ s/^\s*//;

         # if we find "]", we are done
         # "]" が見つかればこれで完了.
         if ($json->incr_text =~ s/^\]//) {
            print "finished.\n";
            exit;
         }

         # if we find ",", we can continue with the next element
         # "," が見つかれば次の要素に進む.
         if ($json->incr_text =~ s/^,//) {
            last;
         }

         # if we find anything else, we have a parse error!
         # (訳注:内容があるのに)何も見つけれなければ, これはパースエラー!
         if (length $json->incr_text) {
            die "parse error near ", $json->incr_text;
         }

         # else add more data
         # それ以外の時はデータを追加.
         sysread $fh, my $buf, 65536
            or die "read error: $!";
         $json->incr_parse ($buf); # void context, so no parsing
                                   # void context, つまりパースはまだしない.
      }

これは複雑な例ですが, 複雑さの大半は 正しくあろうとしていることから来ています (もし間違っていたら辛抱してください, この例は実行していないのです:)


マッピング

このセクションでは JSON::XS が Perl の値をどのように JSON の値へと マッピングしているかそしてその逆を行っているかについて説明します. これらのマッピングはほとんどの状況でラウンドトリップ性を保ちながら 自動的に"正しいことを行う"ように設計されています(入力したものは 等価な何かとして出力されます).

もっと進むために: 以下の説明に注意してください, 小文字の perl は Perl インタプリタを示し, 大文字の Perl は抽象化した Perl 言語 そのものを参照します.

JSON -> PERL

object

JSON オブジェクトは Perl のハッシュリファレンスになります. オブジェクトキーの順序は保存されません(JSONもそれ自身ではオブジェクト キーの順序を保存しません).

array

JSON の配列は Perl では配列リファレンスになります.

string

JSON の文字列は Perl では文字列スカラーになります - JSON のユニコード コードポイントは Perl 文字列で同じコードポイントとして表現されます, なので手作業でのデコードは不要です.

number

JSON での数値はその範囲と小数部に応じて perl での整数, 数値( 浮動小数点)若しくは文字列スカラーになります. Perl レベルでは, これらの違いはなく, 全ての詳細な変換は Perl によって処理されますが, 整数の方が若干メモリ 消費が少なく浮動小数点数よりも実質より多くを表現できることが あります.

数値が数字のみからなっているときには, JSON::XS はそれを整数値として表現しようとします. もしこれができなければ精度を失うことがなければ 数値(浮動小数点数)として表現します. それ以外であれば文字列値として残します (この時 JSON 数値は JSON 文字列へと再エンコードされるため ラウンドトリップ能力が失われます).

分数若しくは指数部を含んだ数値は精度を失うことなしに数値 (浮動小数点数)として表現されます (この時完全なラウンドトリップ能力は失わることがありますが, JSON 数値はまだ JSON 数値へと再エンコードされます).

true, false

これらの JSON アトムはそれぞれ JSON::XS::true 及び JSON::XS::false になります. これらはだいたい正確に 数値 1 及び 0 のように動作するようにオーバーロード されています. スカラーが JSON 真偽値なのかどうかは JSON::XS::is_bool 関数を使って判断できます.

null

JSON の null アトムは Perl では undef になります.

PERL -> JSON

Perl から JSON へのマッピングは若干複雑です, Perl は本当に型の無い言語で あり, そのため Perl の値を意味するJSON の型は推測するしかありません.

ハッシュリファレンス

Perl のハッシュリファレンスは JSON のオブジェクトになります. ハッシュのキー(若しくは JSON オブジェクト)には固有の順序はないため 同じプログラムでも実行するたびに変化するけれどプログラムの1回の 同じ実行内であれば大抵同じになる疑似ランダム順でエンコードされます. JSON::XS はオプションでハッシュキーをソートすることが出来ます( canonicalフラグで決定されます), このため同じデータ構造で( そして同じ設定とJSON::XSのバージョンで)あれば同じ JSON テキストへと シリアライズされます, しかしこれは実行時のオーバーヘッドとなる上に 役立つのはまれなことです, 例えば幾つかの JSON テキストで 他のテキストと等価か比較したいとき.

配列リファレンス

Perl の配列リファレンスは JSON の配列となります.

その他のリファレンス

その他のブレスされていないリファレンスは大抵は受け付けられずに 例外が投げられますが, 整数 0 及び 1 のリファレンスだけは JSON のアトム false 及び true へと変換されます. ぱっとみを 分かり易くするために JSON::XS::false 及び JSON::XS::true を 使うことも出来ます.

   encode_json [\0, JSON::XS::true]      # yields [false,true]
JSON::XS::true, JSON::XS::false

これらの特殊な値はそれぞれ JSON true 及び JSON false の値になります. やりたければ \1 及び \0 を直接使うこともできます.

ブレスされたオブジェクト

ブレスされたオブジェクトは JSON では直接は受け付けられません. それを行うためのいくつかのオプションとして allow_blessed 及び convert_blessed メソッドを参照してください: 基本的に, 例外を投げるか, ブレスされていないかのようにそのリファレンスを エンコーディングするか, 若しくは独自のシリアライザメソッドを提供するか の選択になります.

シンプルなスカラー

単純な Perl スカラー(リファレンスではない全てのスカラー)は エンコードがとても難しいオブジェクトです: JSON::XS は 未定義のスカラーは JSON の null 値に, エンコーディグングまでに スカラコンテキストで使われたスカラーは JSON 文字列に, そして それ以外の全ては数値としてエンコードします:

   # dump as number
   # 数値としてダンプ.
   encode_json [2]                      # yields [2]
   encode_json [-3.0e17]                # yields [-3e+17]
   my $value = 5; encode_json [$value]  # yields [5]

   # used as string, so dump as string
   # 文字列として使ったので文字列としてダンプ.
   print $value;
   encode_json [$value]                 # yields ["5"]

   # undef becomes null
   # undef は null に.
   encode_json [undef]                  # yields [null]

文字列化を行うことで強制的にJSON文字列にすることが出来ます:

   my $x = 3.1; # some variable containing a number
   "$x";        # stringified
   $x .= "";    # another, more awkward way to stringify
   print $x;    # perl does it for you, too, quite often
   
   my $x = 3.1; # 数値を含んでいる変数
   "$x";        # 文字列化
   $x .= "";    # 文字列化する awk っぽい方法
   print $x;    # かわりに perl がやってくれる

数値化を行うことで強制的にJSON 数値型にすることが出来ます:

   my $x = "3"; # some variable containing a string
   $x += 0;     # numify it, ensuring it will be dumped as a number
   $x *= 1;     # same thing, the choice is yours.
   
   my $x = "3"; # 文字列を含んでいる変数
   $x += 0;     # 数値化, これによって数値としてダンプされることを保証
   $x *= 1;     # 同様, 好きな方を選んでください

いまのところ他の型への強制を 読みづらくなることなしにおこなうことはできません. もし その方法が必要であれば私に問い合わせてください (なぜそれが必要なのかの説明を忘れないでくださいね :).


エンコーディング/文字集合フラグの説明

関心のある読者はエンコーディングか文字集合(codeset)を示す いくつかのフラグ - utf8, latin1 そして ascii を 目にしているでしょう. これらはそれらが何をするのか 戸惑うかもしれません, なのでここで簡単に比較してみます.

utf8encode で作られた(そして decode が期待する) JSON テキストが UTF-8 エンコードされているかどうかを, そして latin1 及び asciiencode がそのコード範囲の 外側になる文字をエスケープするかどうかのみを制御します. これらのフラグはどちらもそれぞれにぶつかり(conflict)ますが, けれどもいくつかの組み合わせはわかりにくいでしょう.

全てのフラグは encode 及び decode に対照的に関係する点に 気をつけてください, つまり, いずれかの組み合わせでエンコードされた テキストは, 同じ組み合わせが使われたときに正しくデコードできます - 多くの場合は, もしエンコードとデコードで異なるフラグ設定を 使った場合にはどこかでバグとなるでしょう.

詳しい説明は以下に続きます. "コードセット" は単純に文字とコードポイントの組の抽象的な集合で, エンコーディングがこれらのコードポイント値を取って, 私たちの場合ではオクテットへとエンコードされます. Unicode が(それ以外もそうですが)コードセットであり, UTF-8 がエンコーディングです, そして ISO-8859-1 (= latin 1) 及び ASCII はコードセットであり そして同時にエンコーディングでもあります, これは混乱しますが.

utf8 フラグが無効になっているとき

utf8 が無効になっているとき(デフォルト)は, encode/decode は Unicode 文字列を生成/予期します, つまり, 高位の Unicode 文字 (> 255)はそのような文字へと エンコードされ, 同じようなそのような文字はそのようにデコードされます, それらはそれぞれ Unicode コードポイント若しくは Unicode 文字としての "(再)解釈"を除いて変更はされません (Perl においては, これらは おかしな/奇妙な/馬鹿なことをしているのでなければ文字列中で同じ物です).

これは自分でエンコードしたいとき (例えば UTF-16 でエンコードされた JSON テキストが欲しい)や他のレイヤがエンコードしてくれる (例えば始めは本当に UTF-8 では欲しくはなくて ファイルハンドルから 端末に出力するときに透過的に Perl が別の時にエンコードしてくれるとき) に便利です.

utf8 フラグが有効になっているとき

utf8-フラグが有効になっていると, encod/decode は 全ての文字を対応する UTF-8 多バイト列を使って 全ての文字をエンコードし, 入力が UTF-8 でエンコードされている ことを期待するようになります, つまり, 入力文字列の "文字" には UTF-8 が許さない 255 より大きな値は存在しません.

utf8 フラグは従って2つのモードのスイッチとなります: 無効になっていると Perl では Unicode 文字列として扱われ, 有効になっていると Perl では UTF-8 エンコードされたオクテット/バイナリ 文字列として扱われます.

latin1 若しくは ascii フラグが有効になっているとき

latin1 (若しくは ascii) が有効になっていると, encode は順序値が 255 より大きい(ascii では 127 より大きい)文字 をエスケープして, 残りの文字を utf8 フラグで指定された文字に エンコードします.

utf8 が無効になっていると, その結果はその文字集合は 正しくエンコードもされます (両方とも Unicode の正当なサブセットで, Unicode 文字列の 256 未満の全ての文字は ISO-8859-1 文字列と同じであり, Unicode 文字列の 128 未満の全ての文字は Perl における ASCII 文字列と同じです).

utf8 が有効になっていると, この時も正しく UTF-8 エンコードされた 文字列を得ることができます, これらのフラグにかかわらず, いくつかの文字は \uXXXX でエスケープされます.

ISO-8859-1 でエンコードされた文字列は UTF-8 エンコーディングとは互換性がないことに注意してください, ASCII エンコードされた文字列では互換性があるにもかかわらずです. これは ISO-8859-1 エンコーディングは UTF-8 のサブセットではないためです, (ISO-8859-1 コードセット は Unicode のサブセットであるにもかかわらず), そして ASCII は UTF-8 のサブセットであるにもかかわらず.

意外なことに, deocode はこれらのフラグを無視します, そして全ての入力は utf8 フラグに支配されます. それが無効であれば, ISO-8859-1 及び ASCII エンコードされた 文字列としてデコードされます, これはどちらも Unicode の厳密なサブセットで あるためです. それが有効になっていれば, UTF-8 エンコードされた文字列を 正しくデコードできます.

つまり latin1 及び asciiutf8 フラグとは互換がありません - これらは JSON の出力エンジンが文字をエスケープするかどうかにだけ 作用します.

latin1 の主な用法としてはバイナリデータを比較的効率的に JSON として格納できる点でしょうか, 多くの JSON デコーダとの 相互運用性を壊しますが.

ascii の主な用法としては出力が 127 を超える値を含まないように 強制させる点です, これは出力された文字を UTF-8, ISO-8859-1, ASCII, KOI8-R や他の文字集合及び8ビットエンコーディングとして 処理できることを意味します, そしてそれでもなお同じデータ構造を 復元できます. これは JSON 転送チャンネルが 8-bit クリーンで なかったり, 壊され(mangled)たり(例えばメール等)する時でも, ASCII は世界で使われているほとんどの 8-bit 及び多バイトエンコーディング の適切なサブセットであるため動作します.

JSON と YAML

JSON は YAML のサブセット(若しくはほぼサブセット)であると 時々耳にするでしょう. これは, しかしながら, とても ヒステリックなことであり, 真実からはほど遠いことです. 一般的には, JSON::XS が正しい YAML をはき出すように設定する 方法はありません.

もしどうしても JSON::XS を使って YAML を生成しなければ ならないのであれば(今後のバージョンで変更されるかもしれない) 以下のアルゴリズムを使ってみるとよいでしょう:

   my $to_yaml = JSON::XS->new->utf8->space_after (1);
   my $yaml = $to_yaml->encode ($ref) . "\n";

これは大抵正しい YAML としてパース可能な JSON テキストを 生成するでしょう. しかし YAML は JSON の持っていない (簡単な)オブジェクトキーの長さに対するハードコードされた 制限を持っているので, ハッシュキーが YAML で許可されている 1024 文字より短くなるように気をつけてください.

それ以外にもまだ知らない非互換もあるかもしれません. 一般的に JSON の生成ロジックを使って YAML を 生成及びその逆, 若しくは YAML パーサを使って JSON のパースを及びその逆を行うべきではありません: 厳密な相互運用に関する問題を引き起こす可能性が高いでしょう.

(*)

私は Brian Ingerson (YAML 仕様の著者の一人)から何回も このパラグラフを削除するように圧力を受けました, 彼が実際に非互換が存在することを認めているにもかかわらずです. 私はこの"JSON は YAML"の嘘で個人的にかみつかれて, 混乱してこれらの記事を人々に伝えておくと言いました, なので同じ問題に何回も陥らないでください. この後, Brian は私のことを(引用)全く役に立たない間抜け(引用ここまで) と呼びました.

私の意見としては, YAMLやいくつかのその提案に関する間違った 説明に関して本当に明白に話題をだした人々に圧力を掛けたり 侮蔑したりするのではなく, 私は JSON の仕様(これは難しくも 長くもありません)を読んでみることを優しく提案します, 実際の互換性に関する嘘を何年にもわたって広めたり それが真実ではないと指摘した人を黙らせようとしたりするのではなく.

速度

以下の表にあるように, JSON::XS は驚くくらい高速です. このデータは JSON::XS 配布物の中の eg/bench プログラムで生成されました, あなたの 環境でも簡単に比較してみることができます.

はじめにとても短い一行の JSON 文字列を使って様々なモジュールで比較 したものです:

   {"method": "handleMessage", "params": ["user1", "we were just talking"], \
   "id": null, "array":[1,11,234,-5,1e5,1e7, true,  false]}

これは1秒間あたりの ecode/decode 数を示します (JSON:XS は 関数インターフェース, JSON::XS/2 は OO インターフェースで pretty-printing とハッシュキーソートを有効にしたもの, JSON::XS/3 は shrink を有効にしたものを使っています). 大きい方が優秀です.

   module     |     encode |     decode |
   -----------|------------|------------|
   JSON 1.x   |   4990.842 |   4088.813 |
   JSON::DWIW |  51653.990 |  71575.154 |
   JSON::PC   |  65948.176 |  74631.744 |
   JSON::PP   |   8931.652 |   3817.168 |
   JSON::Syck |  24877.248 |  27776.848 |
   JSON::XS   | 388361.481 | 227951.304 |
   JSON::XS/2 | 227951.304 | 218453.333 |
   JSON::XS/3 | 338250.323 | 218453.333 |
   Storable   |  16500.016 | 135300.129 |
   -----------+------------+------------+

これによると, JSON::XS は pretty-printing とキーのソートを 有効にしていても JSON::DWIW よりエンコードおよそ5倍, デコードで およそ3倍, そして JSON よりおよそ40倍高速です. 小さなデータに有利な Storable でも比較しています.

もっと長いテスト文字列(おおよそ 18KB, Yahoo! Locals 検索 API (http://dist.schmorp.de/misc/json/long.json で生成)で試してみた結果:

   module     |     encode |     decode |
   -----------|------------|------------|
   JSON 1.x   |     55.260 |     34.971 |
   JSON::DWIW |    825.228 |   1082.513 |
   JSON::PC   |   3571.444 |   2394.829 |
   JSON::PP   |    210.987 |     32.574 |
   JSON::Syck |    552.551 |    787.544 |
   JSON::XS   |   5780.463 |   4854.519 |
   JSON::XS/2 |   3869.998 |   4798.975 |
   JSON::XS/3 |   5862.880 |   4798.975 |
   Storable   |   4445.002 |   5235.027 |
   -----------+------------+------------+

ここでも, JSON::XS は大きく抜き出ています(驚くほどではないけれど デコードが高速な Storable を除いて).

大きなUnicode文字を対象に含んでいる大きな文字列では, 幾つかの モジュール(例えば JSON::PC) の方が JSON::XS より速いことも ありますが, それが返す結果はUnicode処理が無い(若しくは間違っている) 為に壊れています. それ以外では適切なデコード及びエンコードは拒否されて しまいます, そのためこのケースにおける対等な比較を準備するのは不可能 です.


セキュリティ的な考慮点

プロトコル内で JSON を使っているのであれば 信頼されていない潜在的に敵意のある生成物について いつかの方法について話しておく必要があります.

はじめに, 使用する JSON デコーダはセキュアであるべきです, つまり, どんなバッファオーバフローも無いべきです. 明らかに, このモジュールはそれを保証するべきでありそうあるようにとても がんばっていますが, あなたはそれを知らないでしょう.

2番目に, リソース枯渇攻撃を無効化する必要があります. これは 受け付ける JSON テキストのサイズを制限するか確認するべきと いうことです, これによってリソースが枯渇したときに よい方向に働くでしょう(例えば安全にクラッシュできるように プロセスを分割したり). JSON テキストのオクテット若しくは 文字単位でのサイズは Perl 構造をデコードするために必要な リソースのサイズのよい指標になります. JSON::XS は JSON テキストのサイズを調べることができますが, それが既にメモリ内にあるのでは遅すぎます, なので文字列を受け付ける前にサイズを調べる必要があるでしょう.

3番目に, JSON::XS はオブジェクトや配列をデコードする時に, C スタックを使って再帰します. C スタックは限界のあるリソースです: 例えば 8MB のスタックサイズをもつ私の amd64 マシンでは 180k 個の ネストした配列をデコードできますが, ネストした JSON オブジェクトでは 14k 個だけでした(croak時に一時領域を解放するために perl 自身が深く 再帰するためです). この制限を超えたとき, プログラムはクラッシュ します. ここでは慎重に, デフォルトのネスト制限は 512 に設定されて います. もしあなたの処理でもっとちいさなスタックしかないのであれば, max_depth メソッドを使って適切な設定に調整するべきです.

他にも何か私の考えの及ばないところで暴発することがあるかもしれません. そうなってしまったときには残ったかけらを持っておいてください. 助言できるようにいつも門戸をひらいていますので...

また JSON::XS はエラーメッセージの中に Perl データ構造の中身を 漏らしてしまうことがある点を忘れないでください, つまり公開したくはない情報をシリアライズするときには JSON::XS の投げる例外を信頼できる人以外の前にでないように するべきでしょう.

そして最後にとはいえ大きなことではないのですが, 私も考えていなかった他の何かがあなたを爆破することが あるかもしれません. そのようなことがあったときには, その欠片を集めておいてください. 私はいつでもヒントを 歓迎していますので.

もしブラウザの JavaScript で利用するためのパケットとして返すために JSON::XS を使っているのなら 幾つかの攻撃ベクタに対して脆弱でないかを確認するために http://jpsykes.com/47/practical-csrf-and-json-security を見ておくべきです(これらは本当にブラウザ設計のバグですが, メジャーなブラウザの開発者たちは安全性ではなく機能のみに 注意しているのであなたがバグに対しては注意を払っておく 必要があります).


スレッド

このモジュールはスレッドセーフに関しては考慮しておらず また Perl がスレッドサポートを得るまでこれを変更する予定もありません (恐ろしく低速な"threads"と呼ばれる単に遅くて肥大化した プロセスのシミュレーションではなく, とても高速で, 安価で, より良い, fork を使いましょう).

(実際のところ動作はするでしょう, でも警告はしましたよ).


バグ

このモジュールの目標として正しくあることがありますが, 不幸なことにこれはバグがないということを意味しているわけではあなく, 設計にバグがないことと考えています. このモジュールはまだとても若く テストも十分なわけではありません. バグ報告がきたらすぐに修正するでしょう.

rt.cpan.org や他のバグ報告サービスの利用は控えてください. 故あって連絡用のアドレスはモジュールに記載しています.


関連項目

The json_xs command line utility for quick experiments.


著者

 Marc Lehmann <schmorp@schmorp.de>
 http://home.schmorp.de/

和訳

 山科 氷魚 (YAMASHINA Hio) <hio@hio.jp>

原典: JSON-XS VERSION 2.23-2.231. 翻訳日: 2008-10-25. (JSON-XS-0.2, 2007-03-23)

JSON::XS - 正しくて高速な JSON シリアライザ/デシリアライザ

索引

JSON::XS - 正しくて高速な JSON シリアライザ/デシリアライザ