=head1 名前

attributes - 変数若しくは関数の属性を取得/設定

=head1 概要

  sub foo : method ;
  my ($x,@y,%z) : Bent = 1;
  my $s = sub : method { ... };

  use attributes ();	# optional, to get subroutine declarations
  my @attrlist = attributes::get(\&foo);

  use attributes 'get'; # import the attributes::get subroutine
  my @attrlist = get \&foo;

=head1 説明

関数の宣言と定義ではそれに関連した属性のリストを任意で持つことが
できます. (変数の C<my> 宣言もできますが, 後述の警告も参照して
ください.) Perl はこれらの宣言を, 呼び出す場所と属性リストと
ともに宣言されようとしているものの情報をこのモジュールに渡すことで
これらの宣言を処理します. 特に, 上の最初の例は次のものと等価です:

    use attributes __PACKAGE__, \&foo, 'method';

2番目の例は次と等価です:

    use attributes ();
    my ($x,@y,%z);
    attributes::->import(__PACKAGE__, \$x, 'Bent');
    attributes::->import(__PACKAGE__, \@y, 'Bent');
    attributes::->import(__PACKAGE__, \%z, 'Bent');
    ($x,@y,%z) = 1;

ここでは多くの展開がなされます.

B<警告>: 変数に対する属性の宣言はまだ進歩の途上にあります. 
これらの宣言の意味とインターフェースは今後のバージョンで
変更される可能性があります. これらは今後くる意味を体験する
のを目的として提供されています. この機能の現在の実装には
頼らないでください.

現在 Perl 自身(若しくは見方によってはこのモジュールが直接)で
処理される属性はわずかです. しかし, あるパッケージ用の属性という
ものが拡張メカニズムとして使うことができます. (後述の
L</Package-specific Attribute Handling>を参照してください.)

関数の属性の設定はコンパイル時に起きます. C<our> 宣言での変数属性も
コンパイル時に適用されます. しかし, C<my> 変数は実行時に属性の
適用が行われます. これは属性が適用される前に C<my> の実行時構成に
I<到達>しなければならないことを意味します. 例えば:

    my $x : Bent = 42 if 0;

は $x に 42 を代入することI<も>変数に C<Bent> 属性が適用される
こともありません.

知らない属性の設定は致命的なエラーとなります. (このエラーは
トラップできますが, その C<eval> 野中でコンパイルは停止します.) 
全てが小文字からなるけれど組み込みの属性ではない名前(例えば”foo")
を設定すると B<-w> 若しくは C<use warnings 'reserved'> では
警告を発生します.

=head2 組み込みの属性

以下のものは関数用の組み込み属性です

=over 4

=item locked

B<5.005 スレッドのみです! "locked" 属性の使用は今だと
廃止された "Perl 5.005 スレッド" によるスレッド実装を
使っているときにだけ意味を持ちます.>

この属性を設定するのはその関数若しくはメソッドが複数のスレッドから
呼び出されるときにだけ意味があります. メソッド関数(つまり後述の
B<method> 属性を持っているもの）に対して設定したときには
Perl はその呼び出し時には実行の前に最初に引数を暗黙にロック
することを保証します. ロックの意味は関数に入った直後に C<lock> 
演算子で明示的に行うのとちょうど同じです.

=item method

参照された関数はメソッドであると提示します. これは先に説明した
B<locked> 属性と一緒に使うときに意味があります. これでマーク
された関数は "Ambiguous call resolved as CORE::%s" (CORE::%s
として処理される曖昧な呼び出し）警告は発生させません.

=item lvalue

参照された関数は左辺値(lvalue)として有効であり代入可能である
ことを示します. 関数は L<perlsub> で説明されているように
変更することのできる値, 例えばスカラー変数等を返さなければ
なりません.

=back

グローバル変数のために C<unique> 属性があります: 
L<perlfunc/our> を参照してください.

=head2 提供されている関数

以下の関数は一般的な使用のためにこのモジュールをロード
したときに提供されます.

=over 4

=item get

This routine expects a single parameter--a reference to a
subroutine or variable.  It returns a list of attributes, which may be
empty.  If passed invalid arguments, it uses die() (via L<Carp::croak|Carp>)
to raise a fatal exception.  If it can find an appropriate package name
for a class method lookup, it will include the results from a
C<FETCH_I<type>_ATTRIBUTES> call in its return list, as described in
L</Package-specific Attribute Handling> below.
Otherwise, only L<built-in attributes|/Built-in Attributes> will be returned.


=item reftype

This routine expects a single parameter--a reference to a subroutine or
variable.  It returns the built-in type of the referenced variable,
ignoring any package into which it might have been blessed.
This can be useful for determining the I<type> value which forms part of
the method names described in L</Package-specific Attribute Handling> below.


=back

Note that these routines are I<not> exported by default.


=head2 Package-specific Attribute Handling

B<WARNING>: the mechanisms described here are still experimental.  Do not
rely on the current implementation.  In particular, there is no provision
for applying package attributes to 'cloned' copies of subroutines used as
closures.  (See L<perlref/Making References> for information on closures.)
Package-specific attribute handling may change incompatibly in a future
release.


When an attribute list is present in a declaration, a check is made to see
whether an attribute 'modify' handler is present in the appropriate package
(or its @ISA inheritance tree).  Similarly, when C<attributes::get> is
called on a valid reference, a check is made for an appropriate attribute
'fetch' handler.  See L</EXAMPLES> to see how the "appropriate package"
determination works.


The handler names are based on the underlying type of the variable being
declared or of the reference passed.  Because these attributes are
associated with subroutine or variable declarations, this deliberately
ignores any possibility of being blessed into some package.  Thus, a
subroutine declaration uses "CODE" as its I<type>, and even a blessed
hash reference uses "HASH" as its I<type>.


The class methods invoked for modifying and fetching are these:


=over 4

=item FETCH_I<type>_ATTRIBUTES

This method receives a single argument, which is a reference to the
variable or subroutine for which package-defined attributes are desired.
The expected return value is a list of associated attributes.
This list may be empty.


=item MODIFY_I<type>_ATTRIBUTES

This method is called with two fixed arguments, followed by the list of
attributes from the relevant declaration.  The two fixed arguments are
the relevant package name and a reference to the declared subroutine or
variable.  The expected return value is a list of attributes which were
not recognized by this handler.  Note that this allows for a derived class
to delegate a call to its base class, and then only examine the attributes
which the base class didn't already handle for it.


The call to this method is currently made I<during> the processing of the
declaration.  In particular, this means that a subroutine reference will
probably be for an undefined subroutine, even if this declaration is
actually part of the definition.


=back

Calling C<attributes::get()> from within the scope of a null package
declaration C<package ;> for an unblessed variable reference will
not provide any starting package name for the 'fetch' method lookup.
Thus, this circumstance will not result in a method call for package-defined
attributes.  A named subroutine knows to which symbol table entry it belongs
(or originally belonged), and it will use the corresponding package.
An anonymous subroutine knows the package name into which it was compiled
(unless it was also compiled with a null package declaration), and so it
will use that package name.


=head2 Syntax of Attribute Lists

An attribute list is a sequence of attribute specifications, separated by
whitespace or a colon (with optional whitespace).
Each attribute specification is a simple
name, optionally followed by a parenthesised parameter list.
If such a parameter list is present, it is scanned past as for the rules
for the C<q()> operator.  (See L<perlop/Quote and Quote-like Operators>.)
The parameter list is passed as it was found, however, and not as per C<q()>.


Some examples of syntactically valid attribute lists:


    switch(10,foo(7,3))  :  expensive
    Ugly('\(") :Bad
    _5x5
    locked method

Some examples of syntactically invalid attribute lists (with annotation):


    switch(10,foo()		# ()-string not balanced
    Ugly('(')			# ()-string not balanced
    5x5				# "5x5" not a valid identifier
    Y2::north			# "Y2::north" not a simple identifier
    foo + bar			# "+" neither a colon nor whitespace

=head1 エクスポート

=head2 Default exports

None.


=head2 Available exports

The routines C<get> and C<reftype> are exportable.


=head2 Export tags defined

The C<:ALL> tag will get all of the above exports.


=head1 例

Here are some samples of syntactically valid declarations, with annotation
as to how they resolve internally into C<use attributes> invocations by
perl.  These examples are primarily useful to see how the "appropriate
package" is found for the possible method lookups for package-defined
attributes.


=over 4

=item 1.

Code:


    package Canine;
    package Dog;
    my Canine $spot : Watchful ;

Effect:


    use attributes ();
    attributes::->import(Canine => \$spot, "Watchful");

=item 2.

Code:


    package Felis;
    my $cat : Nervous;

Effect:


    use attributes ();
    attributes::->import(Felis => \$cat, "Nervous");

=item 3.

Code:


    package X;
    sub foo : locked ;

Effect:


    use attributes X => \&foo, "locked";

=item 4.

Code:


    package X;
    sub Y::x : locked { 1 }

Effect:


    use attributes Y => \&Y::x, "locked";

=item 5.

Code:


    package X;
    sub foo { 1 }

    package Y;
    BEGIN { *bar = \&X::foo; }

    package Z;
    sub Y::bar : locked ;

Effect:


    use attributes X => \&X::foo, "locked";

=back

This last example is purely for purposes of completeness.  You should not
be trying to mess with the attributes of something in a package that's
not your own.


=head1 関連項目

L<perlsub/Private Variables via my()> and
L<perlsub/Subroutine Attributes> for details on the basic declarations;
L<attrs> for the obsolescent form of subroutine attribute specification
which this module replaces;
L<perlfunc/use> for details on the normal invocation mechanism.